echo off

rem ご注意
rem このファイルを作成した 気ままさん は
rem このファイルを実行して発生した起こったすべての事柄において責任を負いません。
rem 自己責任にてお願いいたします。
rem これに同意をいただけない場合はこのファイルの使用は許可いたしかねます。

rem 配布ページ：http://kimama91.seesaa.net/article/HmFilerClassic.html
rem 連絡先：ブログのメールフォームにて

rem 改良したファイルは許可いらずで自由配布可能ですが
rem このファイル単体を改造しないでそのまま配布する場合は
rem 配布ページの URL を貼ってください。
rem バージョンアップでファイルの URL が変わるためです。

rem ------------------------------------------
rem 何これ

rem 秀丸ファイラーの設定を常に同じ状態 ( フォルダ、タブの選択状況など ) で起動したい場合に
rem ( 秀丸ファイラー を起動して何かをすると設定が書き込まれてしまうので )

rem このファイルを EXE に変換して実行すると
rem 設定を勝手に書き戻してから秀丸ファイラーを起動する物です 
rem 
rem 秀丸ファイラー専用というわけではなく
rem このファイルを書き換える応用力があり、書き戻す設定ファイルが判明していれば
rem どのアプリでも可能です、多分

rem ------------------------------------------
rem 使い方

rem このファイルは基本的に EXE に変換して使用します。
rem EXE に変換したものを配布しないのは
rem こんな誰かもわからないような EXE を怖くて実行できるか
rem ということが起こらないためです、自分で作れば安全です。

rem EXE の作成方法には VisualBat というアプリが便利です。
rem このファイルを VisualBat にドラッグして
rem ビルド → exe化 ( 非表示 ) → ファイル名を HmFilerClassic2.exe で保存

rem HmFilerClassic.exe と同じ場所に置き
rem HmFilerClassic.exe と同じ場所に SettingBakup というフォルダを作成
rem その中に HmFilerClassic.ini を置き
rem HmFilerClassic2.exe を実行すると勝手に
rem SettingBakup のファイルから上書きされ HmFilerClassic.exe を起動します。

rem 書き換えは SET の箇所を自分の環境に書き換えるだけで
rem SET [ここには任意の変数] = の　＝の後ろのみ、＝の前はいじっては駄目。

rem ------------------------------------------
rem 先頭に rem とあるのはコメント行の意味で rem がある行は実行されません

rem このファイルを実行形式にした場合のEXEファイル名
rem EXE化して使用する場合は、このファイル名と作成したファイル名が一致する必要があります
SET myEXE=HmFilerClassic2.exe

rem 起動するアプリ名
SET startEXE=HmFilerClassic.exe

rem このファイルを実行している場所をフルパスで取得
FOR %%I IN (%1.bat %1.exe %1 %myEXE%) DO (
    IF NOT "%%~$PATH:I"=="" (
        SET name=%%~$PATH:I
    )
)

rem ------------------------------------------
cls
rem 上で取得したフルパスから
rem ファイル名を取り除く、FolName_001 へ一時飛び戻ってくる
Call :FolName_001 %name%
echo %name%

rem 上書きされる設定ファイル名
SET DEL_fol="%name%HmFilerClassic.ini"
echo %DEL_fol%

rem 上書きする設定ファイル名
SET Copy_fol="%name%SettingBakup\HmFilerClassic.ini"
echo %Copy_fol%

rem 実行するアプリ名 ( この行は書き換えません )
SET exe="%name%%startEXE%"
echo %exe%

rem このファイルを実行して動作を確認する場合は、下の rem を削除
rem 動作確認後 EXE に変換する前は、必ず先頭に rem を付けること、処理が止まります
rem pause は一時待機のコマンドです
rem pause

rem ------------------------------------------
rem 起動しようとするアプリが起動しているか、確認
TASKLIST | FIND "%startEXE%" > NUL
IF NOT ERRORLEVEL 1  (
	ECHO %startEXE% は起動しています。
	rem 起動していたらデスクトップに呼び出し ( トレイアイコン常住設定ONが必要 )
	start "" %exe%

	rem 一度終了して呼び出す場合はすぐ下の３行の rem を全部削ります
	rem その場合は上の start "" %exe% の前に rem を追加します
	rem さらに下の goto :END の部分の先頭に rem を追加します
	rem taskkill /IM "%startEXE%" /F
	rem TIMEOUT /T 1
	rem goto :copy_001
	goto :END

) ELSE (
	ECHO 対象APが起動していません。
	goto :copy_001
)

rem ------------------------------------------
:copy_001
rem 設定ファイルを削除する場合は以下の rem を削ります
rem del %DEL_fol%

rem 設定ファイルのコピーです
copy /y %Copy_fol% %DEL_fol%

rem １秒待機
TIMEOUT /T 1

rem アプリを起動
start "" %exe%

rem 終了へ
goto :EOF

rem ------------------------------------------
:FolName_001
rem フルパスからファイル名を除外
set name=%~dp1

rem call の行まで戻る
goto :EOF

:END
exit