echo off

rem [ はじめに ]
rem indicator_Reset_v1.02.bat
rem インジケーター ( トレイアイコン ) のデータを保存・復元・削除します。

rem 想定 OS は Windows10 creators です。
rem Win10 のバージョンによって \TrayNotify 内のファイル名が
rem 変化しているのでまとめて \TrayNotify を保存・復元・削除しています。

rem 配布先
rem http://kimama91.seesaa.net/article/indicator_Tray_Ico_save.html

rem 使用は自己責任にて。
rem このファイルを使用して発生した
rem いかなる事案も責任を取りません。
rem これに同意いただけない場合は、
rem ダウンロードとご使用は許可いたしかねます。

rem Win10 の各バージョンに対応するための
rem ファイルの改良・改良したファイルの配布はお好きにどうぞ、連絡も当然不要です。

rem [ 経歴 ]
rem v1.00 完成
rem v1.01 taskkill の位置が前後にずれていたので修正
rem v1.02 説明のおかしなところを修正

rem -----
rem [ 設定 ]

rem ここにレジストリを保存するディレクトリ名 ( 例：r:\ 、必ず最後尾に \ )
SET DirReg=C:\インジケーター\

rem ここにレジストリを保存するファイル名 ( 例：インジケーター.reg 、必ず最後尾に .reg )
SET FileReg=インジケーター.reg

rem 双方とも ファイル＆フォルダ名に半角スペースが入っていても
rem "" で囲う必要はありません
rem -----

:op
cls
echo.
echo インジケーター ( トレイアイコンの整列 ) 設定
echo.
echo [ 1 ] 保存　／　[ 2 ] 復元
echo.
echo [ 3 ] 削除　／　[ 4 ] 保存フォルダを開く
echo.
echo 設定保存フォルダ ＞ %DirReg%%FileReg%
echo.
choice /c:1234
IF ERRORLEVEL 4 GOTO open
IF ERRORLEVEL 3 GOTO del
IF ERRORLEVEL 2 GOTO load
IF ERRORLEVEL 1 GOTO save

:open
cls
start "" "%DirReg%"
goto :end_2

:save
cls
echo.
echo インジケーター 設定 保存
echo.
if not exist "%DirReg%" MD "%DirReg%"
reg export "HKEY_CURRENT_USER\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify" "%DirReg%%FileReg%" /y
goto :end_1

:load
cls
echo.
echo インジケーター 設定 復元
echo.
taskkill /IM "explorer.exe" /F
reg delete "HKEY_CURRENT_USER\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify" /f
reg import "%DirReg%%FileReg%"
echo.
echo explorer.exe 再起動をします。
echo.
pause
start "" "explorer.exe"
goto :end_2

:del
cls
echo.
echo インジケーター 設定 削除
echo.
taskkill /IM "explorer.exe" /F
reg delete "HKEY_CURRENT_USER\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify" /f
echo.
echo explorer.exe 再起動をします。
echo.
pause
start "" "explorer.exe"
goto :end_2

:end_1
pause

:end_2