echo off
cls

rem WinRAR はシェアウェアです。
rem 使用していてお気に入りになりましたら購入してあげてくださいませ。

rem このバッチファイルは WinRAR の作者様とは一切関係ありませんので
rem このファイルのことでお問い合わせはご遠慮くださいませ。

rem 一応説明を書いておきましたので書き換えてご使用ください。
rem このファイルは自己責任にてご使用ください。
rem ご理解いただけない方は使用を禁止いたします。
rem -----

rem rar.exe の位置
rem バッチファイルを rar.exe のフォルダに置くなら set rar1="%~dp0\rar.exe"
set rar1="D:\Program Files\WinRAR\rar.exe"

rem 圧縮・解凍時に使用するPassword (使用しない場合は""にする)↓
rem ひらがな、カタカナ、漢字、英数字、空白( "59 63" とか )もOK 
set pass="59 63"

rem このバッチファイルに圧縮ファイルをドラッグしたら解凍する kaitow_1 へ飛ぶ
if not "%1" == "" goto kaitow_1

rem 圧縮します a を指定、-r でサブフォルダも圧縮
set rar2=a -r

rem バックアップフォルダ名 ( 最後に必ず\を付加 )
set in="R:\test\"

rem バックアップファイル拡張子 全てファイルの場合は -n*.* を指定
set file=-n*.txt -n*.jpg

rem バックアップの 出力フォルダ\ファイル名 r:\ に bakup_ と出力
set out="r:\bakup_"

rem 日付を付加します YYMMDDで何年何月何日 HHMMで何時何分
rem 20XX年にする場合はYYYYMMDD
set rar3=-agYYMMDD-HHMM

rem 除外ファイル Thumbs.d? と 拡張子 .bak を圧縮から除外
set noarc=-xThumbs.d? -x*.bak

rem -rr5 リカバリレコード 5％付加
rem -ed  空のファイルを格納しない
rem -m3  圧縮率 3を指定、0 から 5 まで指定可能
rem -ep3 ドライブレターを含むフルパス格納
rem (これを付けないとドラッグした時に自動で元の位置に解凍できません)
set option=-rr5 -ed -m3 -ep3

rem 圧縮確認をします
echo.
echo 以下のフォルダを圧縮します。
echo %in%
echo.
echo 圧縮する拡張子
echo %file%
echo.
echo 除外ファイル
echo %noarc%
echo.
echo パスワード %pass%
echo.
echo 出力先
echo %out%
echo.
echo [Y] はい ／ [N] 中止
echo.
choice /c:ny
IF ERRORLEVEL 2 GOTO arc_1
IF ERRORLEVEL 1 GOTO end_1
GOTO end_1

:arc_1
cls

rem 圧縮実行
%rar1% %rar2% %out% %in% %rar3% %option% %noarc% %file% -hp%pass%

rem 一時停止 (処理を確認できます、見ない場合は削除してok)
echo.
pause

rem 終了へ飛びます
goto end_1


rem ---
rem ここからは解凍になります
:kaitow_1

rem 解凍は x を指定します
rem -ep3 でドライブレターを含むフルパス指定 (圧縮したフォルダ位置に書き戻す)
set rar2=x -ep3

rem 解凍確認をします
echo.
echo 以下のファイルを解凍します。
echo %1
echo.
echo [Y] はい (全て上書き) ／ [N] 中止
echo.
choice /c:ny
IF ERRORLEVEL 2 GOTO kaitow_2
IF ERRORLEVEL 1 GOTO end_1
GOTO end_1

:kaitow_2
cls

rem 解凍実行 このバッチファイルにドラッグしたファイルを解凍します
rem -y 全ての質問に「はい」、選択したい場合は消してください 
%rar1% -y %rar2% "%1" -p%pass%

rem 一時停止 (処理を確認できます、見ない場合は削除してok)
echo.
pause

rem 終了へ飛びます
goto end_1


rem ---
:end_1